home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FM Towns: Free Software Collection 10
/
FM Towns Free Software Collection 10.iso
/
fb386
/
tool
/
tiffload
/
tiffload.bas
next >
Wrap
BASIC Source File
|
1995-01-09
|
3KB
|
73 lines
10 '
20 ' フリコレTIFFローダー
30 '
40 '初期設定
50 CLEAR:SCREEN 0:COLOR 7,0,7:CLS:CONSOLE 0,20,2:DIM F2(49),F3$(49)
60 SCREEN@ 0:ON ERROR GOTO *ERROR
70 '始まり
80 PRINT "┌──────────────┐"
90 PRINT "│フリコレTIFF画像ローダー│"
100 PRINT "│BY HIWATASHI │"
110 PRINT "└──────────────┘"
120 PRINT "ドライブを指定してください例 A ";:A$=INPUT$(1):PRINT A$
130 INPUT "パスを設定して下さい 例 \GRAPHICS\ ";B$
140 PRINT "”"+A$+":"+B$+"”以下のTIFFファイルをサーチします"
150 PRINT "OK? (Y/N)":GOSUB *YN
160 IF C=0 THEN 120
170 '初期設定終わり
180 PRINT "~COFFEE BREAK~":FOR I=0 TO 49:F2(I)=3:NEXT
190 'メインプログラム
200 *MAIN
210 FILES A$+":"+B$,C,A&
220 IF A&(1)>2 THEN DIM F1$(A&(1)) ELSE PRINT "ファイルがありません"
230 FILES A$+":"+B$,N,F1$
240 FOR I=F2(Z) TO A&(1)
250 PRINT MID$(F1$(I),1,47)
260 IF MID$(F1$(I),10,3)="TIF" THEN GOSUB *TIFF
270 IF MID$(F1$(I),17,9)="--<DIR>--" THEN GOSUB *DOWN
280 NEXT
290 F2(Z)=3:Z=Z-1
300 IF Z<0 THEN END ELSE B$=F3$(Z):ERASE F1$:GOTO *UP
310 'TIFFファイルのロード
320 *TIFF
330 PRINT "TIFFファイルをサーチしました":PRINT "表示しますか? (Y/N)"
340 GOSUB *YN
350 IF C=0 THEN RETURN
360 CONSOLE 0,0:Y=0:E$="":FOR H=1 TO 8
370 IF KMID$(F1$(I),H,1)=" " THEN H=8 ELSE E$=E$+KMID$(F1$(I),H,1):NEXT
380 CLS:LOAD@ A$+":"+B$+E$+".TIF"
390 C$=INPUT$(1):CLS:PRINT A$+":"+B$+E$+".TIF":C$=INPUT$(1)
400 CONSOLE 0,20:SCREEN@ 0:COLOR 7,0,7:CLS:PRINT A$+":"+B$+E$+".TIF":CLS
404 C$=INPUT$(1)
410 RETURN
420 '下がる
430 *DOWN
440 PRINT "このディリクトリの検索を行いますか?":GOSUB *YN
450 IF C=0 THEN RETURN
460 F2(Z)=I:F3$(Z)=B$:Z=Z+1:FOR H=1 TO 8
470 IF KMID$(F1$(I),H,1)=" " THEN H=8 ELSE B$=B$+KMID$(F1$(I),H,1)
480 NEXT:B$=B$+"\":ERASE F1$:GOTO *MAIN
490 '上がる
500 *UP
510 I=F2(Z):FILES A$+":"+B$,C,A&:DIM F1$(A&(1)):FILES A$+":"+B$,N,F1$
520 RETURN
530 'イエス・ノーの判断
540 *YN
550 C$=INPUT$(1):IF C$="N" OR C$="n" THEN C=0:RETURN
560 IF C$="Y" OR C$="y" THEN C=1:RETURN
570 PRINT "(Y/N)":GOTO *YN
580 'エラー・画面モード切り換えルーチン
590 *ERROR
600 IF ERL=380 AND ERR=112 AND Y<2 THEN Y=Y+1:SCREEN@ Y:RESUME
610 PRINT "エラーがありました";:X=0
620 IF ERL=210 AND ERR=72 THEN PRINT "ディスクの準備ができていません":X=1
630 IF ERL=230 AND ERR=63 THEN PRINT "指定のディリクトリがありません":X=1
640 IF ERL=210 AND ERR=60 THEN PRINT "そのドライブは設定されてません":X=1
650 IF ERL=380 THEN PRINT "ファイルのオープンに失敗しました":X=2
660 PRINT "何かキーを押して下さい":C$=INPUT$(1)
680 IF X=1 THEN RUN
690 IF X=2 THEN PRINT "リトライ?(Y/N)":GOSUB *YN
700 IF X=2 AND C=1 THEN RESUME
704 IF X=2 THEN PRINT "何かキーを押して下さい":RESUME NEXT
710 PRINT "番号~ ";ERR;" 行番は";ERL